StockFetcher Forums · Filter Exchange · Bullish Candles and Bullish Candlestick Patterns<< >>Post Follow-up
SAFeTRADE
646 posts
msg #131829
- Ignore SAFeTRADE		 10/8/2016 1:16:58 PM

My attempt at capturing Bullish Candlesticks and Bullish Candlestick Patterns as they come across my path in the wild.

Fetcher[
close above 5
average volume(30) above 250000
not etf
not otcbb
draw ma(50)
draw ma(20)
draw ma(200)
draw Slow Stochastics Fast %K(12,3)
draw cci(60) line at 100

/**********************************GapUp******************************/
set{Xgapup, open / high 1 day ago}
/******************************End Gapup*****************************/

/***********************Kicker Signal***************************/
set{k, count(close 1 day ago below Day Position(0.25,1) 1 day ago,1)}
set{k2, count(open above the high 1 day ago,1) * count(
the close above the Day Position(0.75,1),1)}
set{kicker,k * k2}
/***********************End Kicker Signal**********************/

/***********************Bullish Engulfing***********************/
set{be, count(low below low 1 day ago,1)}
set{be2, count(close 1 day ago is below the Day Position(0.25,1) 1 day ago,1) *
count(open below close 1 day ago,1)}
set{be3,count(close above open 1 day ago,1)}
set{be4, be * be2}
set{bu_Engulfing, be4 * be3}
/***********************End Bullish Engulfing********************/

/***********************Hammer Filter****************************/
set{hammer,count(open above the Day Position(0.75,1),1) * count(
close is above the Day Position(0.75,1),1)}
/*******************End Hammer Signal**************************/

/**********************The Piercing Signal***********************/
set{ps, count(open below low 1 day ago,1) * count(close is above the Day Position(0.75,1) 1 day ago,1)}
set{ps2, count(low 1 day ago is below low 2 days ago,1)}
set{piercing_signal, ps * ps2}
/***********************End Piercing Signal*************************/

/************************Dojis OB_OS*****************************/
set{range, high - low}
set{tolerance, range * 0.01}
set{diff, close - open}
set{clop, abs(diff)}
set{pstop, close * 1.10}

set{clophi, count(clop below tolerance,1) * count(Slow Stochastics Fast %K(12,3) above 79,1)}
set{cloplo, count(clop below tolerance,1) * count(Slow Stochastics Fast %K(12,3) below 21,1)}
/****************************End Dojis OB OS***************************/

/*********************************Morning Star Signal***************************/
set{ms, count(low 1 day ago below low 2 days ago,1)}
set{ms2, count(close is above the Day Position(0.67,1) 2 days ago,1)}
set{morn_st, ms * ms2}
set{morn_sta, count(Slow Stochastics Fast %K(12,3) below 25,1)}
set{morn_star, morn_sta * morn_st}
/***************************End Morning Star Signal*****************************/

/********************************Left Right Combo********************************/

set{dojih1, clophi 1 day ago}
set{dojil1, cloplo 1 day ago}

set{l, count(open below close 1 day ago,1) * count(close above close 1 day ago,1)}
set{l1, count(close is above the Day Position(0.50,1),1) * l}

set{lrh, dojih1 * l1}
set{lrl, dojil1 * l1}

/******************************End Left Right Combo****************************/

/******************************Display Signal Columns***********************/
add column separator
add column xgapup{Gapup}
add column separator
add column kicker
add column separator
add column lrl{l/rcombolo}
add column lrh{l/rcombohi}
add column separator
add column bu_Engulfing
add column separator
add column hammer
add column separator
add column piercing_signal
add column separator
add column morn_star
add column separator
add column clophi{doji_ob}
add column cloplo{doji_os}
add column separator

/*********************************************Plot Indicators************************/
add column Slow Stochastics Fast %K(12,3){stoch12}
]
StockFetcher Forums · Filter Exchange · Bullish Candles and Bullish Candlestick Patterns<< >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.